Description

The modulus operator, %, gives you the remainder when dividing two numbers. For example: 3 % 2 yields 1 because 3 divided by 2 leaves a remainder of 1.

Try this:

$count = 0;
for ( 1 .. 10 ) {
    print ++$count % 2 ? "on" : "off";
    print "\n";
}

You see how easily this can be used to create alternating behavior in a script. Now for a bigger example.

# Setup our rows styles --------------------------------------------
my $style = <<HTMLstyleHere;
<style>
.myTable   { border:1px solid #369; width:90%; }
.indexRow  { background-color: #9ab; padding:2px; }
.firstRow  { background-color: #ddf; padding:2px; }
.secondRow { background-color: #dfd; padding:2px; }
</style>
HTMLstyleHere

# meta data and data -----------------------------------------------
my @headings = qw( Name Location Email Rating );

my @data = ( [ 'Ted', 'Detroit', 'ted@motorcity.org', '++++' ],
             [ 'Delia', 'Moscow', 'shanghai@marked.net', '++++++' ],
             [ 'Jeff', 'Metzger', 'jeffb@pollywog.com', '+++++' ],
             [ 'Kara', 'Las Cruces', 'slayr@wicca.org', '+++' ],
             );

# Do style and the header row --------------------------------------
print
    $style,
    '<div align="center">',
    '<table class="myTable" cellpadding="3" cellspacing="0">',
    '<tr>',
    ( map { "<td class=\"indexRow\"><b>$_</b></td>\n" } @headings ),
    "</tr>\n\n";

# Setup our counter to alternate row classes/colors ------------------
my $counter = 0;

# Iterate through data -----------------------------------------------
for my $row ( @data ) {

    my $td_class = ++$counter % 2 ? "firstRow" : "secondRow";

    print
        "<tr>",
        ( map { "<td class=\"$td_class\">$_</td>\n" } @{$row} ),
        "</tr>\n\n";
}
print "</table></div><br />\n";

Output

Discussion

This is really just the most basic use of this technique. It can be used for anything where you need to keep track of intervals. Use it for dividing columns as well as rows.

Here’s a way to get 15 columns.

$count = 0;
print ++$count % 15 ? "$_ " : "$_\n" for ( 100 .. 200 );

100 101 102 103 104 105 106 107 108 109 110 111 112 113 114
115 116 117 118 119 120 121 122 123 124 125 126 127 128 129
130 131 132 133 134 135 136 137 138 139 140 141 142 143 144
145 146 147 148 149 150 151 152 153 154 155 156 157 158 159
160 161 162 163 164 165 166 167 168 169 170 171 172 173 174
175 176 177 178 179 180 181 182 183 184 185 186 187 188 189
190 191 192 193 194 195 196 197 198 199 200